收藏! 用DAX自定义函数一键生成日期表(附代码)

在PowerBI数据分析中，日期表是最基础也最关键的维度表。过去，我们曾介绍过多种创建日期表的方法，包括Excel公式法、Power Query的M函数法以及传统的DAX写法。参考：

玩PowerBI必备的日期表制作方式汇总

分享一个更实用的Power BI日期表

这里向大家介绍一种全新的、更高效的方式—利用DAX自定义函数一键生成日期表！

关于DAX自定义函数的用法请参考我之前的详细介绍：

Power BI模块化DAX时代来临！一文全面了解DAX自定义函数

在PowerBI Desktop中，我们需要做的只有一步，就是先定义一个DAX自定义函数，这里命名为Pbixq.Calendar，完整代码如下：

DEFINE  FUNCTION Pbixq.Calendar=
    (
        YearStart:int64,
        YearEnd:int64
    )=>
    ----------------------------------------------------------------
    --制作日期表的相关参数，可根据需要修改
    VAR WeekNumberType = 2
        // WEEKNUM第二个参数类型，控制每周的开始时间，返回此周在一年中的编号
        // 1，一周从星期日开始 
        // 2，一周从星期一开始 
    VAR WeekDayType = 2       
        // WEEKDAY第二个参数类型，控制每周的开始时间，返回周几的编号
        // 1，一周从星期日 (1) 开始，到星期六 (7) 结束，编号 1 到 7
        // 2，一周从星期一 (1) 开始，到星期日 (7) 结束，编号 1 到 7
        // 3，一周从星期一 (0) 开始，到星期日 (6) 结束，编号 0 到 6
    VAR StartMonthofFY=7  //财务年度开始月份
    -----------------------------------------------------------------
    RETURN
    GENERATE(
        CALENDAR(DATE(YearStart,1,1),DATE(YearEnd,12,31)),
        VAR Year = YEAR ( [Date] )
        VAR Month = MONTH ( [Date] )
        VAR Quarter = QUARTER( [Date] )
        VAR Day = DAY( [Date] )
        VAR YearMonth = Year * 100 + Month
        VAR Weekday = WEEKDAY( [Date] , WeekDayType ) 
        VAR WeekOfYear = WEEKNUM( [Date] ,WeekNumberType )
        RETURN 
        ROW (
            "年" , Year ,
            "季" , Quarter ,
            "月" , Month ,
            "日" , Day ,
            "年度名称" , "Y" & Year ,
            "季度名称" , "Q" & Quarter ,
            "年度季度", Year & "Q" & Quarter ,
            "年季编号" , ( Year - YearStart )*4 + Quarter,
            "月份名称", FORMAT ( [Date], "OOOO" ,"zh-cn" ) ,
            "英文月份", FORMAT ( [Date], "MMM" ) ,
            "年度月份" , YearMonth ,
            "年月编号" , ( Year - YearStart )*12 + Month,
            "年度第几日" , INT( [Date] - DATE( Year , 1 , 1 ) + 1 ),      
            "星期编号" , Weekday ,
            "星期名称" , FORMAT( [Date] , "AAAA","zh-cn" ) ,
            "星期英文" , FORMAT( [Date] , "DDD" ) ,  
            "年度第几周" , WeekOfYear ,
            "周编号", "W" & RIGHT( 0 & WeekOfYear , 2 ) ,
            "年周" , Year & "W" & RIGHT( 0 & WeekOfYear , 2 ) ,
            "日期编码" , Year * 10000 + Month * 100 + Day,
            "财年",IF( Month<StartMonthofFY , "FY"&Year , "FY"&Year+1 ),
            "财季","FQ"&QUARTER(EDATE([Date],-StartMonthofFY+1)),
            "今日",IF([Date]<TODAY(),FORMAT([Date],"YYYY-MM-DD"),IF([Date]=TODAY(),"今日"))
        )
    )    

然后只需要填写开始年度和结束年度两个参数，就可以自动生成该期间的日期表了。

对于日期表创建这个高频需求，UDF提供了完美的解决方案，相比传统方法，使用DAX自定义函数创建日期表有诸多优势：

标准化：团队内所有成员使用同一套日期表生成逻辑，确保一致性

灵活性：通过参数控制日期表的维度和结构，满足不同需求

可维护性：只需维护一个函数定义，所有使用该函数的日期表都会自动更新

易用性：非技术用户也能轻松生成专业级的日期表

DAX自定义函数的引入，彻底改变了我们在PowerBI中使用DAX的方式，日期表生成只是开始，后面还会看到更多实用强大的UDF应用场景！

PowerBI星球的最新版内容合辑，值得你收藏学习：

「PowerBI星球」内容合集
「链接」

.